{"id":55000847,"date":"2012-08-01T00:00:00","date_gmt":"2020-05-22T21:47:45","guid":{"rendered":"http:\/\/access-im-unternehmen.aix-dev.de\/aiu\/?p=847"},"modified":"-0001-11-30T00:00:00","modified_gmt":"-0001-11-30T00:00:00","slug":"Drucker_im_Griff","status":"publish","type":"post","link":"https:\/\/access-im-unternehmen.de\/Drucker_im_Griff\/","title":{"rendered":"Drucker im Griff"},"content":{"rendered":"

\"\"<\/p>\n

Berichte drucken Kein Problem: Dialoge wie die Seiteneinstellungen und der Drucken-Dialog liefern doch alles, was das Herz an Einstellungsmöglichkeiten begehrt. Aber was, wenn Sie mal per VBA eingreifen möchten – zum Beispiel, weil der Benutzer ganz einfach zwei Exemplare eines Dokuments mit einem Mausklick drucken möchte Oder weil Sie zur Laufzeit die Anzahl der Spalten eines Berichts einstellen möchten Dies lässt sich natürlich per VBA erledigen. Dieser Beitrag zeigt, wie es funktioniert.<\/b><\/p>\n

Alle Drucker auflisten<\/b><\/p>\n

Wenn auf Ihrem System mehr als ein Drucker installiert ist, was in Anbetracht der vielen gängigen virtuellen Drucker wahrscheinlich ist, möchten Sie diese zunächst auflisten.<\/p>\n

Eine durch Semikola getrennte Liste können Sie später beispielsweise als Datensatzherkunft eines Kombinationsfeldes verwenden (s. Bild 1). Zunächst einmal geben wir diese Liste jedoch einfach im Direktfenster aus, und zwar mit diesem Befehl:<\/p>\n

\"pic001.png\"<\/p>\n

Bild 1: Auswahl von Druckern per Kombinationsfeld<\/span><\/b><\/p>\n

Debug.Print Druckerliste<\/pre>\n
Die dazu passende Funktion Druckerliste <\/b>hat folgenden Code:<\/p>\n
Public Function Druckerliste() As String\r\n    Dim strTemp As String\r\n    Dim objDrucker As Printer\r\n    Dim i As Integer\r\n    For i = 0 To Printers.Count - 1\r\n        Set objDrucker = Printers(i)\r\n        strTemp = strTemp & ";" & i & ";" & objDrucker.DeviceName\r\n    Next i\r\n    If Len(strTemp) > 0 Then\r\n        strTemp = Mid(strTemp, 2)\r\n    End If\r\n    Druckerliste = strTemp\r\nEnd Function<\/pre>\n
Diese Funktion verwendet die Auflistung Printers<\/b>, die für alle dem System bekannten Drucker je ein Element enthält. Um alle Drucker zu ermitteln, durchläuft die Funktion eine Schleife über alle enthaltenen Elemenge, wobei die Anzahl mit der Eigenschaft Count <\/b>der Printers<\/b>-Auflistung ermittelt wird. Innerhalb der Schleife wird das jeweilige Printer<\/b>-Element mit der Variablen objDrucker<\/b> referenziert. Der Index sowie der Druckername werden in einer durch Semikola separierten Liste erfasst, die beispielsweise so aussieht:<\/p>\n
0;Snagit 9;1;SnagIt 8;2;PDF-XChange 3.0;3;Microsoft XPS Document Writer;4;HP Officejet 4500 G510a-f;5;Fax;6;Brother QL-570 LE;7;Adobe PDF;8;\\\\MACBOOKPRO\\Canon Inkjet iP2600 series<\/p>\n
Ein Printer<\/b>-Objekt besitzt neben DeviceName <\/b>noch einige weitere Eigenschaften. Um diese übersichtlich darzustellen, verwenden wir ein Formular.<\/p>\n
Dieses enthält ein Kombinationsfeld zur Auswahl des Druckers, das sinnvollerweise mit der Funktion Druckerliste <\/b>gefüllt wird, sowie einige Steuerelemente, welche weitere Eigenschaften des ausgewählten Printer<\/b>-Objekts anzeigen.<\/p>\n
Nach der Auswahl des Druckers soll das Formular die über das Printer<\/b>-Objekt verfügbaren Daten wie in Bild 2 anzeigen.<\/p>\n
\"pic002.png\"<\/p>\n
Bild 2: Ausgabe von Druckerinformationen<\/span><\/b><\/p>\n
Dazu soll zunächst beim Öffnen des Formulars das Kombinationsfeld cboDrucker <\/b>mit dem Ergebnis der Funktion Druckerliste <\/b>gefüllt werden. Außerdem soll das Kombinationsfeld direkt beim Öffnen des Formulars den ersten Eintrag der Liste anzeigen.<\/p>\n
Schließlich sorgt ein Aufruf der Funktion DruckereigenschaftenEinlesen <\/b>dafür, dass die übrigen Steuerelemente des Formulars gefüllt werden:<\/p>\n
Private Sub Form_Load()\r\n    Me!cboDrucker.RowSource = Druckerliste\r\n    Me!cboDrucker = Me!cboDrucker.ItemData(0)\r\n    DruckereigenschaftenEinlesen\r\nEnd Sub<\/pre>\n
Der Code der Prozedur DruckereigenschaftenEinlesen <\/b>sieht so aus:<\/p>\n
Private Sub DruckereigenschaftenEinlesen()\r\n    Dim objDrucker As Printer\r\n    Set objDrucker = Printers.Item(CLng(Me!cboDrucker))\r\n    With objDrucker\r\n        Me!txtBottomMargin = .BottomMargin\r\n        Me!txtLeftMargin = .LeftMargin\r\n        Me!txtRightMargin = .RightMargin\r\n        Me!txtTopMargin = .TopMargin\r\n        Me!cboColorMode = .ColorMode\r\n        Me!txtColumnSpacing = .ColumnSpacing\r\n        Me!txtCopies = .Copies\r\n        Me!chkDataOnly = .DataOnly\r\n        Me!chkDefaultSize = .DefaultSize\r\n        Me!txtDrivername = .DriverName\r\n        Me!cboDuplex = .Duplex\r\n        Me!cboItemLayout = .ItemLayout\r\n        Me!txtItemsAcross = .ItemsAcross\r\n        Me!txtItemSizeHeight = .ItemSizeHeight\r\n        Me!txtItemSizeWidth = .ItemSizeWidth\r\n        Me!cboOrientation = .Orientation\r\n        Me!cboPaperBin = .PaperBin\r\n        Me!cboPaperSize = .PaperSize\r\n        Me!txtPort = .Port\r\n        Me!cboPrintQuality = .PrintQuality\r\n        Me!txtRowSpacing = .RowSpacing\r\n    End With\r\nEnd Sub<\/pre>\n
Die Prozedur ermittelt zunächst den im Kombinationsfeld cboDrucker <\/b>ausgewählten Index und liest das entsprechende Printer<\/b>-Objekt in die Variable objDrucker <\/b>ein. Danach schreibt sie die Werte der einzelnen Variablen in die entsprechenden Steuerelemente.<\/p>\n
Die Eigenschaften erwarten Long<\/b>– und Boolean<\/b>-Werte, wobei die Long<\/b>-Werte teilweise mit Konstanten gefüllt werden können.<\/p>\n
Die entsprechenden Konstantenlisten sind in der Eigenschaft Datensatzherkunft <\/b>der Kombinationsfelder hinterlegt, für das Steuerelement cboOrientation <\/b>beispielsweise wie folgt:<\/p>\n
1;"acPRORPortrait";2;"acPRORLandscape"<\/pre>\n
Dadurch stehen dann die beiden Zeichenfolgen acPRORPortrait <\/b>und acPRORLandscape <\/b>zur Auswahl bereit.<\/p>\n
Damit die Daten bei Auswahl eines neuen Druckers im Kombinationsfeld cboDrucker <\/b>aktualisiert werden, löst dies die Prozedur Nach Aktualisierung <\/b>des Kombinationsfeldes aus:<\/p>\n
Private Sub cboDrucker_AfterUpdate()\r\n    DruckereigenschaftenEinlesen\r\nEnd Sub<\/pre>\n
Hier ist zu erwähnen, dass einige Eigenschaften erst in Zusammenhang mit dem zu druckenden Bericht mit sinnvollen Daten gefüllt werden – mehr dazu weiter unten.<\/p>\n
Drucker auswählen<\/p>\n
Um die Auswahl der Drucker zu erleichtern, haben wir außerdem eine Ereignisprozedur hinterlegt, die beim Betätigen der Nach oben<\/b>– und der Nach unten<\/b>-Taste ausgelöst wird und jeweils den nächsten beziehungsweise den vorherigen Eintrag auswählt:<\/p>\n
Private Sub cboDrucker_KeyDown(KeyCode As Integer, Shift As Integer)\r\n    Select Case KeyCode\r\n        Case 38, 40\r\n            Select Case KeyCode\r\n                Case 38 ''nach oben\r\n                    If CLng(Me!cboDrucker) > 0 Then\r\n                        Me!cboDrucker = Me!cboDrucker - 1\r\n                    End If\r\n                Case 40 ''nach unten\r\n                    If CLng(Me!cboDrucker) < Me!cboDrucker.ListCount - 1 Then\r\n                        Me!cboDrucker = Me!cboDrucker + 1\r\n                    End If\r\n            End Select\r\n            DruckereigenschaftenEinlesen\r\n            KeyCode = 0\r\n    End Select\r\nEnd Sub<\/pre>\n
Da der Index der Printers<\/b>-Auflistung als gebundene Spalte des Kombinationsfeldes übernommen wurde (also 0, 1, 2…), können Sie durch einfaches Addieren oder Subtrahieren des Wertes 1 <\/b>den vorherigen oder den folgenden Listeneintrag auswählen.<\/p>\n
Standarddrucker für Access festlegen<\/b><\/p>\n
Für Access ist ein Standarddrucker festgelegt, den Sie beispielsweise im Drucken<\/b>-Dialog finden (s. Bild 3). Dieser Drucker wird auch etwa beim Drucken von Berichten verwendet, wenn dort kein anderer Drucker festgelegt ist. Um diesen Standarddrucker per VBA festzulegen, haben wir im Formular zur Auswahl der Drucker eine Schaltfläche namens cmdStandarddrucker <\/b>hinterlegt. Diese löst die folgende Prozedur aus, wobei zunächst der im Kombinationsfeld ausgewählte Drucker ermittelt und dann durch Zuweisung an die Eigenschaft Printer <\/b>des Application<\/b>-Objekts als Standarddrucker festgelegt wird:<\/p>\n
\"pic003.png\"<\/p>\n
Bild 3: Der Drucken-Dialog von Access mit dem Standarddrucker<\/span><\/b><\/p>\n
Private Sub cmdStandarddrucker_Click()\r\n    Dim objDrucker As Printer\r\n    Set objDrucker = Printers.Item(CLng(Me!cboDrucker))\r\n    Application.Printer = objDrucker\r\nEnd Sub<\/pre>\n
<\/p>\n
Der hier festgelegte Drucker wird beim Erstellen neuer Berichte als Standarddrucker für diesen Bericht verwendet. Wenn Sie anschließend einen anderen Standarddrucker festlegen, behält der Bericht den zum Zeitpunkt der Erstellung gültigen Standarddrucker.<\/p>\n
Standarddrucker für einen Bericht festlegen<\/b><\/p>\n
Wenn Sie einen Standarddrucker für einen Bericht festlegen möchten, der auch bei änderung des Access-Standarddruckers beibehalten wird, müssen Sie den Bericht im Entwurf öffnen. Wenn Sie diese änderung manuell vornehmen möchten, erledigen Sie dies, indem Sie zunächst den Bericht in der Entwurfsansicht anzeigen und dann den Dialog Seite einrichten <\/b>öffnen.<\/p>\n
Dort wählen Sie unter Drucker für … <\/b>die Option Spezieller Drucker <\/b>aus. Mit einem Klick auf die Schaltfläche Drucker… <\/b>öffnen Sie einen weiteren Dialog, mit dem Sie den gewünschten Dialog auswählen können (s. Bild 4). Das Festlegen eines speziellen Druckers kann beispielsweise sinnvoll sein, wenn die Abmessungen des Berichts auf einen bestimmten Drucker abgestimmt sind.<\/p>\n
\"pic004.png\"<\/p>\n
Bild 4: Festlegen eines speziellen Druckers für einen Bericht<\/span><\/b><\/p>\n
Um diese änderung per VBA vorzunehmen, öffnen Sie den Bericht ebenfalls in der Entwurfsansicht (gegebenenfalls unsichtbar), stellen erst die Eigenschaft UseDefaultPrinter <\/b>auf False <\/b>ein und legen dann mit der Eigenschaft Printer <\/b>den speziellen Drucker fest:<\/p>\n
Public Sub BerichtMitEigenemStandarddrucker_Einstellen()\r\n    Dim objDrucker As Printer\r\n    Dim rpt As Report\r\n    Dim strReport As String\r\n    strReport = "rptBerichtMitStandarddrucker"\r\n    DoCmd.OpenReport strReport, acViewDesign, , , acHidden\r\n    Set rpt = Reports(strReport)\r\n    rpt.UseDefaultPrinter = False\r\n    rpt.Printer = Printers(6)\r\n    DoCmd.Close acReport, strReport, acSaveYes\r\nEnd Sub<\/pre>\n
Anschließend wird der Bericht geschlossen und gespeichert.<\/p>\n
Bericht mit einem bestimmten Drucker ausgeben<\/b><\/p>\n
Das Festlegen eines speziellen Druckers für einen Bericht ist eine Methode, einen Bericht mit einem bestimmten Drucker auszugeben. Es gibt noch zwei weitere Arten, dies durchzuführen.<\/p>\n
Die erste funktioniert nur für Berichte, für die kein spezieller Drucker festgelegt wurde. Dort stellen Sie einfach temporär den aktuellen Access-Drucker auf einen alternativen Drucker ein, drucken den Bericht und setzen den Access-Drucker dann wieder auf die Standardeinstellung zurück.<\/p>\n
Die zweite Methode gelingt unabhängig davon, ob Sie für den Bericht einen speziellen Drucker festgelegt haben. Dort öffnen Sie den Bericht, stellen den Berichtsdrucker auf einen alternativen Drucker ein, drucken diesen und schließen den Bericht wieder.<\/p>\n
Beispiele für diese Vorgehensweise finden Sie im Formular frmDruckerAuswaehlen<\/b> (s. Bild 5).<\/p>\n
\"pic005.png\"<\/p>\n
Bild 5: Drucken eines Berichts mit einem alternativen Drucker<\/span><\/b><\/p>\n
Beim Laden des Formulars wird die Prozedur aus Listing 1<\/a><\/span> ausgelöst. Sie verwendet eine erweiterte Version der Funktion Druckerliste<\/b>, die nun mit den zwei optionalen Parametern strStandard <\/b>und intStandard <\/b>arbeitet. Der Parameter strStandard <\/b>erwartet den Namen des als Standard zu markierenden Druckers, der Parameter intStandard <\/b>liefert den Index dieses Druckers in der Auflistung Printers <\/b>zurück. Dadurch kann das mit der Funktion Druckerliste gefüllte Kombinationsfeld gleich auf den Standarddrucker eingestellt werden.<\/p>\n
Listing 1: Füllen des Kombinationsfeldes mit allen Drucken und Vorauswahl des Standarddruckers<\/p>\n
Private Sub Form_Load()\r\n    Dim strStandard As String\r\n    Dim intStandard As Integer\r\n    strStandard = Application.Printer.DeviceName\r\n    Me!cboAccessdrucker.RowSource = Druckerliste(strStandard, intStandard)\r\n    Me!cboAccessdrucker = Me!cboAccessdrucker.ItemData(intStandard)\r\nEnd Sub<\/pre>\n
Das Formular besitzt außerdem ein Kombinationsfeld, dass alle Berichte der aktuellen Datenbank anzeigt. Es wird mit der folgenden Abfrage gefüllt:<\/p>\n
SELECT Name FROM MSysObjects WHERE Type=-32764 ORDER BY Name;<\/pre>\n
Nach der Auswahl eines der Berichte soll das Kombinationsfeld cboDruckenBericht ebenfalls mit der Liste der Drucker gefüllt und der Standarddrucker für diesen Bericht ausgewählt werden. Außerdems soll das Kontrollkästchen chkStandarddrucker <\/b>anzeigen, ob für den Bericht der Standarddrucker verwendet wird oder ob ein spezieller Drucker für diesen Bericht festgelegt wurde.<\/p>\n
Um dies zu bewerkstelligen, löst das Kombinationsfeld cboBerichte<\/b> nach der Aktualisierung die Ereignisprozedur aus Listing 2<\/a><\/span> aus.<\/p>\n
Listing 2: Ermittlung des Standarddruckers für einen Bericht<\/p>\n
Private Sub cboBerichte_AfterUpdate()\r\n    Dim rpt As Report\r\n    Dim strStandard As String\r\n    Dim intStandard As Integer\r\n    DoCmd.OpenReport Me!cboBerichte, acViewPreview, , , acHidden\r\n    Set rpt = Reports(Me!cboBerichte)\r\n    Me!chkStandarddrucker = rpt.UseDefaultPrinter\r\n    Me!cmdDruckenAccess.Enabled = rpt.UseDefaultPrinter\r\n    strStandard = rpt.Printer.DeviceName\r\n    Me!cboBerichtsdrucker.RowSource = Druckerliste(strStandard, intStandard)\r\n    Me!cboBerichtsdrucker = Me!cboBerichtsdrucker.ItemData(intStandard)\r\n    DoCmd.Close acReport, Me!cboBerichte\r\nEnd Sub<\/pre>\n
Diese Prozedur öffnet den Bericht zunächst verborgen in der Seitenansicht. Auf diese Weise kann er die Eigenschaft UseDefaultPrinter <\/b>auslesen und außerdem den Standarddrucker dieses Berichts ermitteln.<\/p>\n
Mit diesen Informationen kann das Kontrollkästchen chkStandarddrucker <\/b>aktiviert werden. Außerdem füllt diese Prozedur das Kombinationsfeld cboBerichtsdrucker <\/b>mit der Liste der verfügbaren Drucker und zeigt direkt den Standarddrucker des Berichts an. Danach schließt die Prozedur den Bericht wieder.<\/p>\n
Fehlen noch die beiden Schaltflächen cmdDruckenAccess <\/b>und cmdDruckenBericht<\/b>, mit denen der ausgewählte Bericht auf den im jeweiligen Kombinationsfeld ausgewählten Drucker ausgegeben werden soll.<\/p>\n
Die Schaltfläche cmdDruckenAccess <\/b>hat den leichteren Job: Sie stellt einfach nur den im Kombinationsfeld gewählten Drucker als Standarddrucker ein und öffnet den Bericht in der Standardansicht. Anschließend setzt sie den Standarddrucker wieder zurück:<\/p>\n
Private Sub cmdDruckenAccess_Click()\r\n    Set Application.Printer = Printers(CInt(Me!cboAccessdrucker))\r\n    DoCmd.OpenReport Me!cboBerichte, acViewNormal\r\n    Set Application.Printer = Nothing\r\nEnd Sub<\/pre>\n
Die Prozedur, die durch einen Mausklick auf die Schaltfläche cmdDruckenBericht <\/b>ausgelöst wird, öffnet den Bericht in der Entwurfsansicht und stellt dort für die Eigenschaft Printer <\/b>den Standarddrucker für den Bericht ein. Anschließend öffnet sie den Bericht in der Standardansicht, wodurch der Bericht an den angegebenen Drucker gesendet wird.<\/p>\n
Schließlich wird der Bericht geschlossen, ohne die änderungen zu speichern:<\/p>\n
Private Sub cmdDruckenBericht_Click()\r\n    Dim rpt As Report\r\n    DoCmd.OpenReport Me!cboBerichte, acViewPreview, , , acHidden\r\n    Set rpt = Reports(Me!cboBerichte)\r\n    Set rpt.Printer = Printers(CInt(Me!cboBerichtsdrucker))\r\n    DoCmd.OpenReport Me!cboBerichte, acViewNormal\r\n    DoCmd.Close acReport, Me!cboBerichte\r\nEnd Sub<\/pre>\n
Druckeinstellungen ändern<\/b><\/p>\n
Weiter oben haben wir im Formular frmDrucker <\/b>einige Eigenschaften der einzelnen Drucker ausgegeben. Für viele davon liefert das Printer<\/b>-Objekt erst sinnvolle Daten, wenn es als Objekt eines Berichts geöffnet wird.<\/p>\n
Wie Sie an diese Daten gelangen, zeigt das Formular frmBerichtDruckereigenschaften<\/b>. Die dort verwendeten Techniken entsprechen weitgehend den bereits beschriebenen Techniken. Der wesentliche Unterschied ist, dass die Eigenschaften nun nicht mehr dem Printer<\/b>-Objekt des Application<\/b>-Objekts entnommen werden, sondern dem Report<\/b>-Objekt.<\/p>\n
Und es gibt noch einen weiteren Unterschied: Mit dem Formular frmBerichtDruckereigenschaften <\/b>können Sie auch noch die bestehenden Druckereigenschaften anpassen – zur Laufzeit!<\/p>\n
Das bedeutet, dass Sie mit dem Kombinationsfeld cboBerichte <\/b>einen Bericht auswählen, der dann in der Seitenansicht geöffnet wird.<\/p>\n
Wenn Sie dann den Fokus wieder auf das Formular frmBerichtDruckereigenschaften <\/b>verschieben, können Sie die Eigenschaften ändern und die Auswirkungen direkt in der Seitenansicht prüfen (s. Bild 6).<\/p>\n
\"pic006.png\"<\/p>\n
Bild 6: Einstellen der Drucken-Einstellungen für einen geöffneten Bericht<\/span><\/b><\/p>\n
Doch nun eines nach dem anderen. Zunächst sollen nach der Auswahl eines der Berichte die Felder des Formulars mit den entsprechenden Eigenschaften des aktuell für diesen Bericht festgelegten Druckers gefüllt werden.<\/p>\n
Dies erledigt die folgende Prozedur:<\/p>\n
Private Sub cboBerichte_AfterUpdate()\r\n    Dim rpt As Report\r\n    Dim strStandard As String\r\n    Dim intStandard As Integer\r\n    DoCmd.OpenReport Me!cboBerichte, acViewPreview\r\n    Set rpt = Reports(Me!cboBerichte)\r\n    strStandard = rpt.Printer.DeviceName\r\n    Me!cboDrucker.RowSource = Druckerliste(strStandard, intStandard)\r\n    Me!cboDrucker = Me!cboDrucker.ItemData(intStandard)\r\n    DruckereigenschaftenEinlesen rpt.Printer\r\nEnd Sub<\/pre>\n
Die Prozedur öffnet zunächst den gewählten Bericht in der Seitenansicht und referenziert den Bericht mit der Objektvariablen rpt<\/b>.<\/p>\n
Dann liest sie die Druckerliste ein und markiert den für diesen Bericht verwendeten Drucker. Schließlich ermittelt die Prozedur DruckereigenschaftenEinlesen <\/b>die Eigenschaften für den im Parameter übergebenen Drucker – diese Prozedur haben Sie bereits weiter oben kennengelernt.<\/p>\n
Nun folgt der interessante Teil: Das Anpassen einer der Eigenschaften im Formular soll sich direkt auf die Darstellung im Bericht auswirken, spätestens aber beim Anzeigen des Drucken<\/b>-Dialogs. Wenn Sie also beispielsweise die Eigenschaft Orientation <\/b>anpassen, soll die Seitenansicht direkt von Hochformat auf Querformat wechseln und umgekehrt.<\/p>\n
Andere Eigenschaften wirken sich erst beim Anzeigen des Drucken<\/b>-Dialogs aus – so zum Beispiel die Eigenschaft Copies<\/b>, welche die Anzahl der zu druckenden Exemplare angibt.<\/p>\n
Das Übertragen der Einstellungen von den Steuerelementen des Formulars in die entsprechenden Eigenschaften des Printer<\/b>-Objekts ist einfach.<\/p>\n
Dies erledigt jeweils eine Ereignisprozedur, die durch das Ereignis Nach Aktualisierung <\/b>des jeweiligen Steuerelements ausgelöst wird.<\/p>\n
Für das Steuerelement txtCopies<\/b>, das die Anzahl der zu druckenden Exemplare regelt, sieht die Prozedur beispielsweise wie folgt aus:<\/p>\n
Private Sub txtCopies_AfterUpdate()\r\n    Reports(Me!cboBerichte).Printer.Copies = Me!txtCopies\r\nEnd Sub<\/pre>\n
Die übrigen Ereignisprozedur sind genauso aufgebaut.<\/p>\n
Übersicht der Eigenschaften<\/p>\n
Auf diese Weise können Sie die nachfolgend beschriebenen Eigenschaften des Printer<\/b>-Objekts anpassen:<\/p>\n