Das Application-Objekt

Eines der wichtigsten Objekte bei der Programmierung von Access-Anwendungen ist das Application-Objekt. Es bietet viele Eigenschaften und Methoden, die stiefmütterlich behandelt werden. Dabei lohnt es sich, einmal einen Blick darauf zu werfen – dann weiß man im Fall der Fälle, dass es da irgendwo einen passenden Befehl geben muss. Dieser Beitrag zeigt eine Übersicht der Elemente des Application-Objekts und deren Funktion. In weiteren Beiträgen schauen wir uns die Funktion der einzelnen Eigenschaften und Methoden im Detail an.

Application-Objekt im Objektkatalog

Wenn Sie irgendwann einmal vor einer Aufgabe stehen, von der Sie wissen, dass Sie in diesem Beitrag von einer möglichen Lösung gelesen haben, können Sie schnell im Objektkatalog des VBA-Editors nachsehen – dort finden Sie zumindest eine Auflistung der Methoden und Eigenschaften des Application-Objekts. Den Objektkatalog öffnen Sie mit der Taste F2. Oben im Suchfeld geben Sie Application ein und klicken dann auf den gefundenen Eintrag. Die untere Liste liefert dann alle Member dieser Klasse (siehe Bild 1).

Bild 1: Elemente des Application-Objekts

Nachfolgend finden Sie die mehr oder weniger kurzen Beschreibungen der Elemente des Application-Objekts. Elemente für Webdatenbanken oder Elemente für ältere Techniken wie DDE haben wir nicht berücksichtigt. Sie können die Befehle auch ohne vorangestelltes Application nutzen.

AccessError

Diese Funktion erwartet eine Fehlernummer als Parameter und liefert die Beschreibung des Fehlers in der Anwendungssprache (siehe Bild 2). Praktisch, wenn ein Kunde Ihnen nur die Fehlernummer zu einem Fehler liefert und Sie schnell nachsehen wollen, welche Meldung sich dahinter verbirgt.

Bild 2: Ermitteln des Textes eines Access-Fehlers

AddToFavorites

Hat in früheren Versionen von Access die aktuelle Datenbank zur Liste der Favoriten hinzugefügt.

Assistance

Das mit der Eigenschaft Assistance gelieferte Objekt bietet vier Methoden an, die Sie in Bild 3 sehen.

Bild 3: Methoden des Assistance-Objekts

SearchHelp scheint noch die nützlichste Methode zu sein, sie öffnet nach Eingabe eines Suchbegriffs als Parameter die Support-Seite von Microsoft mit den passenden Themen:

Application.Assistance.SearchHelp "Assistance"

Dies funktioniert jedoch nicht gut, denn für dieses Beispiel liefert die Seite keine Suchergebnisse.

AutoCorrect

Das mit AutoCorrect gelieferte Objekt bietet nur eine Eigenschaft namens DisplayAutoCorrectOptions an. Hier mit können Sie einstellen, ob die entsprechenden Optionen angezeigt werden sollen:

Application.AutoCorrect.DisplayAutoCorrectOptions = False

Weitere Informationen zur Autokorrektur finden Sie im Beitrag Autokorrektur-Einträge im Griff (www.access-im-unternehmen.de/1279).

AutomationSecurity

Diese Eigenschaft legt fest, in welchem Sicherheitsmodus Access andere Access-Anwendungen per VBA öffnet (auch einsetzbar von anderen Office-Anwendungen aus). Zum Öffnen wird hier OpenCurrentDatabase verwendet (siehe weiter unten). Es gibt drei Einstellungen:

• msoAutomationSecurityByUI: Verwendet die Einstellungen in den Access-Optionen (zu finden in dem Dialog, der mit Datei|Optionen geöffnet wird, unter Trust Center|Einstellungen für das Trust Center|Makroeinstellungen).
• msoAutomationSecurityForceDisable: Öffnet die Anwendung ohne Aktivierung von VBA, wenn die Makroeinstellung im oben genannten Dialog auf Alle Makros ohne Benachrichtigung aktivieren oder Alle Makros mit Benachrichtigung aktivieren steht. Wenn die Einstellung auf Alle Makros aktivieren steht, hat msoAutomationSecurityForceDisable keine Wirkung.
• msoAutomationSecurityLow: Aktiviert VBA, auch wenn die Makroeinstellung im oben genannten Dialog auf Alle Makros ohne Benachrichtigung aktivieren oder Alle Makros mit Benachrichtigung aktivieren steht.

BrokenReference

Mit dieser Eigenschaft finden Sie heraus, ob das VBA-Projekt kaputte oder nicht vorhandene Verweise enthält:

Public Sub Test_BrokenReference()
     Dim objReference As Access.Reference
     If Application.BrokenReference Then
         MsgBox "Es gibt kaputte Verweise."
         For Each objReference In Application.References
             If objReference.IsBroken Then
                 Debug.Print objReference.Name
             End If
         Next objReference
     Else
         MsgBox "Alle Verweise in Ordnung."
     End If
End Sub

Damit brauchen Sie dann nicht erst die Verweise- beziehungsweise References-Auflistung zu durchlaufen. Das ist erst notwendig, wenn BrokenReference den Wert True liefert. In diesem Fall prüfen wir mit der Eigenschaft IsBroken des Reference-Objekts, ob der aktuell durchlaufene Verweis kaputt ist und geben dann seinen Namen im Direktbereich des VBA-Editors aus.

Build

Gibt die Buildnummer der aktuellen Version von Microsoft Access zurück:

  Application.Build
  14228 

BuildCriteria

Die BuildCriteria-Funktion erlaubt es, Vergleichsausdrücke für verschiedene Datentypen zusammenzustellen. Das ist insbesondere praktisch, wenn man Kriterien etwa für die DLookup-Funktion oder andere Domänenfunktionen zusammenstellen möchte. Die Funktion erwartet folgende Parameter:

• Field: Name des Feldes, nach dessen Inhalt gesucht werden soll
• FieldType: Felddatentyp, zum Beispiel dbText, dbLong, dbCurrency oder dbDate
• Expression: Vergleichsausdruck, zum Beispiel André, 1, Date()

Hier sind einige Beispiele:

Debug.Print BuildCriteria("Vorname", dbText, "André")
Vorname="André"
Debug.Print BuildCriteria("Vorname", dbText, "A*")
Vorname Like "A*"
Debug.Print BuildCriteria("Menge", dbLong, "1")
Menge=1
Debug.Print BuildCriteria("Geburtsdatum", dbDate, Date)
Geburtsdatum=#10/30/2021#
Debug.Print BuildCriteria("Startzeit", dbDate, Now)
Startzeit=#10/30/2021 10:13:4#
Debug.Print BuildCriteria("Einzelpreis", dbCurrency, "10,50")
Einzelpreis=10.5
Debug.Print BuildCriteria("Aktiv", dbBoolean, "Falsch")
Aktiv=False

Wir sehen hier, dass die Funktion recht flexibel ist. Beim Vergleich von Textfeldern ohne Platzhalter wie dem Sternchen (*) wird das Gleichheitszeichen als Operator verwendet, bei solchen mit Sternchen LIKE. Außerdem werden Zeichenketten automatisch in Anführungszeichen eingefasst. Datumsangaben werden in ein SQL-kompatibles Format umgewandelt und in Zahlen werden Kommata durch das aktuell verwendete Dezimaltrennzeichen ersetzt. Außerdem wandelt die Funktion verschiedene Boolean-Werte, zum Beispiel Wahr, direkt in eine verwertbare Form um (True).

Im Beitrag Suchfunktion mit BuildCritera (www.access-im-unternehmen.de/1339) zeigen wir einen Anwendungszweck für diese Funktion.

CloseCurrentDatabase

Schließt die Datenbank in der mit dem Application-Objekt angegebenen Access-Instanz. Sie können diesen Befehl in der aktuellen Access-Instanz wie folgt einsetzen:

Application.CloseCurrentDatabase

Wenn Sie eine Datenbank wie weiter unten unter dem Befehl OpenCurrentDatabase beschrieben in einer eigenen Instanz geöffnet haben, die beispielsweise objAccess heißt, verwenden Sie folgende Anweisung, um die Datenbank zu schließen:

objAccess.Application.CloseCurrentDatabase

CodeContextObject

CodeContextObject liefert den Namen des Objekts, in dem ein Code ausgeführt wird. Es funktioniert nur für Code in den Klassenmodulen von Formular- und Berichtsmodulen. Allerdings können Sie es auch in Routinen nutzen, die von Code in Formularen oder Berichten aus aufgerufen werden. So können Sie etwa in Fehlerbehandlungsroutinen abfragen, in welchem Objekt der Fehler ausgelöst wurde, ohne dass Sie einen Verweis auf das Objekt oder seinen Namen als Parameter an die Fehlerbehandlungsroutine übergeben müssen.

Dazu platzieren wir beispielsweise folgende Prozedur hinter der Ereigniseigenschaft einer Schaltfläche in einem Formular:

Private Sub cmdFehlerAusloesen_Click()
     On Error Resume Next
     Debug.Print 1 / 0
     If Not Err.Number = 0 Then
         Call ErrorHandler
     End If
End Sub

Die von dort aufgerufene Prozedur ErrorHandler legen wir in einem Standardmodul an:

Public Sub ErrorHandler()
     MsgBox "Fehler in ''"  & Application.CodeContextObject.Name & "'' ("  & TypeName(Application.CodeContextObject) & ")"
End Sub

Diese liefert dann den Namen des Formulars sowie den Typ (siehe Bild 4).

Bild 4: Meldung mit Informationen der Eigenschaft CodeContextObject

CodeData

Die Eigenschaft CodeData hat eine sehr ähnliche Funktion wie CurrentData (für die Beschreibung verweisen wir daher auf die Eigenschaft CurrentData, die Sie weiter unten finden). Die Eigenschaft ist für die Nutzung in Access-Add-Ins vorgesehen. Dort können Sie dann mit CodeData auf die Elemente der Add-In-Datenbank zugreifen und mit CurrentData auf die Elemente der aktuell geladenen Datenbank.

CodeDb

CodeDb entspricht im Prinzip der Eigenschaft CurrentDb, daher verweisen wir an dieser Stelle auf die Beschreibung der Eigenschaft CurrentDb, die wir weiter unten vorstellen. Genau wie bei CodeData und CurrentData ist CodeDb für den Einsatz in Access-Add-Ins vorgesehen, um auf das Database-Objekt der Add-In-Datenbank zuzugreifen. Mit CurrentDb hingegen greift man von der Add-In-Datenbank auf das Database-Objekt der aktuell in Access angezeigten Datenbank zu.

CodeProject

CodeProject entspricht im Prinzip der Eigenschaft CurrentProject, daher verweisen wir an dieser Stelle auf die Beschreibung der Eigenschaft CurrentProject, die wir weiter unten vorstellen. Genau wie bei CodeData und CurrentData ist CodeProject für den Einsatz in Access-Add-Ins vorgesehen, um auf das CurrentProject-Objekt der Add-In-Datenbank zuzugreifen. Mit CurrentProject hingegen greift man von der Add-In-Datenbank auf das CurrentProject-Objekt der aktuell in Access angezeigten Datenbank zu.

ColumnHistory

Mit dieser Funktion können Sie den Versionsverlauf der Daten in einem Memofeld abfragen. Dazu erstellen Sie ein Memofeld (Datentyp Langer Text) und stellen dessen Eigenschaft Nur anfügen auf Ja ein (siehe Bild 5). Dann können Sie mit ColumnHistory für einen bestimmten Datensatz den Versionsverlauf auslesen. Für unser Beispiel und den Datensatz mit dem Wert 1 im Feld ID sieht der Aufruf wie folgt aus:

Bild 5: Memofeld zum Anfügen von Texten

Debug.Print Application.ColumnHistory("tblMemofelder", "Memofeld", "ID = 1")

Nachdem wir erst eine, dann eine zweite Zeile eingegeben haben, erhalten wir dieses Ergebnis:

[Version: 30.10.2021 11:27:22 ] Erste Zeile.
[Version: 30.10.2021 11:27:43 ] Erste Zeile.
Zweite Zeile.

COMAddIns

Die Auflistung COMAddIns liefert alle COM-Add-Ins, die für die aktuelle Access-Instanz vorliegen. COM-Add-Ins sind Add-Ins, die im Gegensatz zu Access-Add-Ins mit alternativen Entwicklungsumgebungen erstellt werden, zum Beispiel VB6, .NET oder twinBASIC. Die folgende For Each-Schleife gibt die Beschreibung und die ProgID aller aktuell installierten Elemente aus:

Public Sub Test_COMAddIns()
     Dim objCOMAddIn As COMAddIn
     For Each objCOMAddIn In Application.COMAddIns
         Debug.Print objCOMAddIn.Description,  objCOMAddIn.ProgId
     Next objCOMAddIn
End Sub

CommandBars

Mit der CommandBars-Auflistung greifen Sie auf alle CommandBar-Definitionen der aktuellen Instanz von Access zu. Das mag in Zeiten des Ribbons veraltet zu sein, aber wir wollen die guten, alten Kontextmenüs nicht vergessen: Auch diese lassen sich mit dieser Auflistung ermitteln.

Im folgenden Beispiel durchlaufen wir alle Elemente der CommandBars-Auflistung und geben all diejenigen im Direktbereich des VBA-Editors aus, deren Eigenschaft Type den Wert msoBarTypePopup aufweist:

Public Sub Test_CommandBars()
     Dim cbr As CommandBar
     Debug.Print "Anzahl CommandBars:"  & Application.CommandBars.Count
     For Each cbr In Application.CommandBars
         If cbr.Type = msoBarTypePopup Then
             Debug.Print cbr.Name
         End If
     Next cbr
End Sub

CompactRepair

Diese Methode komprimiert und repariert die im ersten Parameter angegeben Datenbank und erzeugt eine komprimierte und reparierte Version unter dem mit dem zweiten Parameter angegebenen Dateinamen:

Application.CompactRepair  CurrentProject.Path & "\Beispiel.accdb",  CurrentProject.Path & "\Beispiel_Komprimiert.accdb",  True

Mit dem dritten Parameter geben Sie an, ob im Falle von bei der Reparatur entdeckten korrupten Elemente eine Logdatei im Verzeichnis der Datenbank angelegt werden soll.

ConvertAccessProject

Diese Methode konvertiert eine ADP-Datei, also ein Access Data Project, in eine reine Access-Datenbank. Sie erwartet die folgenden Parameter:

• SourceFilename: Name der zu konvertierenden ADP-Datei
• DestinationFilename: Name der zu erstellenden Datei
• DestinationFileFormat: Format der zu erstellenden Datei (zum Beispiel acFileFormatAccess2007)

CreateAccessProject

Mit dieser Methode können Sie eine ADP-Datei, also ein Access Data Project, erzeugen. Sie ist allerdings in neueren Versionen von Access nicht mehr verfügbar und der Aufruf löst den Fehler Das Format ADP (Access Data Project) wird ab dieser Version von Access nicht mehr unterstützt. aus:

Application.CreateAccessProject  CurrentProject.Path & "\Beispiel.adp"

Als zweiten Parameter können Sie noch die Verbindungszeichenfolge für die zu verbindende SQL Server-Datenbank angeben.

CreateAdditionalData

Diese Methode dient dazu, bei einem Export im XML-Format der Daten weitere Tabellen zu den Daten der zu exportierenden Tabelle hinzuzufügen.

Weitere Informationen zu dieser Methode finden Sie im Beitrag XML-Export mit VBA (www.access-im-unternehmen.de/1046).

CreateControl

Die Funktion CreateControl erstellt ein neues Steuerelement in einem Formular und liefert einen Verweis auf das neue Steuerelement als Funktionswert zurück. Diese und die Methoden CreateForm und DeleteControl erläutern wir im Artikel Formulare per VBA erstellen (www.access-im-unternehmen.de/1332).

CreateForm

Die Methode CreateForm erstellt ein neues Formular und liefert einen Verweis auf das neu erstellte Formular als Funktionswert zurück.

CreateGroupLevel

Diese Methode erzeugt in einem Bericht einen neuen Gruppierungs- oder Sortierungsbereich.

Diese und die Methoden CreateReport, CreateReportControl und DeleteReportControl erläutern wir im Artikel Berichte per VBA erstellen (www.access-im-unternehmen.de/1338).

CreateReport

Diese Funktion erstellt einen neuen Bericht und liefert einen Verweis auf den neu erstellten Bericht als Funktionswert zurück.

CreateReportControl

Diese Funktion erstellt ein Steuerelement in einem Bericht und liefert einen Verweis auf das Steuerelement als Funktionswert zurück.

CurrentData

Das mit der Eigenschaft CurrentData gelieferte Objekt liefert Eigenschaften mit verschiedenen Auflistungen:

• AllQueries: Liefert eine Auflistung aller Abfragen der aktuellen Datenbank.
• AllTables: Liefert eine Auflistung aller Tabellen der aktuellen Datenbank.
• AllDatabaseDiagrams, AllFunctions, AllStoresProcedures, AllViews: Liefert Auflistung der SQL Server-Objekte (nur in ADP-Dateien verfügbar, die nicht mehr unterstützt werden)

Der folgende Code gibt die Anzahl der Abfragen und Tabellen aus und anschließend in einer For Each-Schleife die Namen aller Einträge der Auflistung AllTables:

Public Sub Test_CurrentData()
     Dim objObject As AccessObject
     Debug.Print Application.CurrentData.AllQueries.Count
     Debug.Print Application.CurrentData.AllTables.Count
     For Each objObject In Application.CurrentData.AllTables
         Debug.Print objObject.FullName
     Next objObject
End Sub

Achtung: Die beiden Eigenschaften CodeData und CurrentData liefern scheinbar die gleichen Ergebnisse. Das ist nur der Fall, wenn Sie in der aktuell geladenen Datenbank verwendet werden. Wenn Sie die beiden Eigenschaften in einer Add-In-Datenbank nutzen, die ja als Add-In für die Verwendung zusätzlich zu einer anderen Access-Datenbank genutzt wird, dann haben diese einen anderen Kontext:

• CodeData: Liefert dann die Auflistung der Tabellen und Abfragen, die in der Add-In-Datenbank gespeichert sind.
• CurrentData: Liefert dann die Auflistung der Tabellen und Abfragen, die in der in Access geöffneten Datenbank gespeichert sind.

CurrentDb

Die Funktion CurrentDb liefert einen Verweis auf das Database-Objekt der aktuellen Datenbank zurück. Diese Funktion und das Database-Objekt beschreiben wir ausführlich im Beitrag Die CurrentDb-Funktion und das Database-Objekt (www.access-im-unternehmen.de/1111).

CurrentObjectName

Die Eigenschaft CurrentObjectName liefert den Namen des aktuell im Navigationsbereich markierten Elements. Wenn mehrere Elemente markiert sind, liefert die Eigenschaft den Namen des zuerst markierten Elements.

CurrentObjectType

Diese Eigenschaft liefert, wenn ein Objekt im Datenbankfenster angezeigt wird, den Objekttyp des aktuell aktiven Objekts im Datenbankfenster. Ist kein Objekt im Datenbankfenster sichtbar, liefert die Eigenschaft den Objekttyp des aktuell im Navigationsbereich markierten Elements. Wenn mehrere Elemente markiert sind, liefert die Eigenschaft den Objekttyp des zuerst markierten Elements.

Es gibt die folgenden Objekttypen:

• 0: Tabelle (acTable)
• 1: Abfrage (acQuery)
• 2: Formular (acForm)
• 3: Bericht (acReport)
• 4: Makro (acMacro)
• 5: Modul (acModule)

CurrentProject

Mit der CurrentProject-Eigenschaft holen Sie einen Verweis auf das Objekt des gleichnamigen Typs. Es hält einige Methoden und Eigenschaften bereit, die wir uns im Detail im Beitrag Die CurrentProject-Klasse (www.access-im-unternehmen.de/1340) ansehen.

CurrentUser

Gibt den Namen des aktuellen Benutzers der Access-Datenbank zurück, in der Regel Admin. Diese Eigenschaft war früher wichtig, als Access noch das Sicherheitssystem mit der Benutzerverwaltung unterstützt hat.

DAvg

Diese Funktion ermittelt einen Durchschnittswert. Sie finden eine detaillierte Beschreibung im Beitrag Domänenfunktionen (www.access-im-unternehmen.de/317)

DBEngine

Die DBEngine-Eigenschaft liefert einen Verweis auf das gleichnamige Objekt. Dieses stellt Funktionen bereit, um Transaktionen durchzuführen, Datenbanken zu erstellen, Fehlerauflistungen abzufragen und vieles mehr. Im Beitrag Das DBEngine-Objekt (www.access-im-unternehmen.de/1341) beschreiben wir dieses Objekt im Detail.

DCount

Diese Funktion ermittelt die Anzahl der Datensätze mit den angegebenen Kriterien. Sie finden eine detaillierte Beschreibung im Beitrag Domänenfunktionen (www.access-im-unternehmen.de/317)

DeleteControl

Diese Methode löscht ein Steuerelement von einem Formular. Weitere Informationen weiter oben unter CreateControl.

DeleteReportControl

Diese Methode löscht ein Steuerelement von einem Bericht. Für weitere Informationen siehe weiter oben unter CreateGroupLevel.

DFirst

Diese Funktion ermittelt den Wert des angegebenen Feldes des ersten gefundenen Datensatzes mit den angegebenen Kriterien. Sie finden eine detaillierte Beschreibung im Beitrag Domänenfunktionen (www.access-im-unternehmen.de/317)

DLast

Diese Funktion ermittelt den Wert des angegebenen Feldes des letzten gefundenen Datensatzes mit den angegebenen Kriterien. Sie finden eine detaillierte Beschreibung im Beitrag Domänenfunktionen (www.access-im-unternehmen.de/317)

DLookup

Diese Funktion ermittelt den Wert des angegebenen Feldes des ersten gefundenen Datensatzes mit den angegebenen Kriterien. Sie finden eine detaillierte Beschreibung im Beitrag Domänenfunktionen (www.access-im-unternehmen.de/317)

DMax

Diese Funktion ermittelt den maximalen Wert des angegebenen Feldes der gefundenen Datensätze mit den angegebenen Kriterien. Sie finden eine detaillierte Beschreibung im Beitrag Domänenfunktionen (www.access-im-unternehmen.de/317)

DMin

Diese Funktion ermittelt den minimalen Wert des angegebenen Feldes der gefundenen Datensätze mit den angegebenen Kriterien. Sie finden eine detaillierte Beschreibung im Beitrag Domänenfunktionen (www.access-im-unternehmen.de/317)

DoCmd

Das DoCmd-Objekt stellt einige Methoden bereit, die üblicherweise über die Benutzeroberfläche oder als Makrobefehl bereitgestellt werden. Wir stellen diese Methoden ausführlich im Beitrag Das DoCmd-Objekt vor (www.access-im-unternehmen.de/1342).

DStDev

Diese Funktion ermittelt die Standardabweichung des angegebenen Feldes der gefundenen Datensätze mit den angegebenen Kriterien bezogen auf eine Stichprobe. Sie finden eine detaillierte Beschreibung im Beitrag Domänenfunktionen (www.access-im-unternehmen.de/317)

DStDevP

Diese Funktion ermittelt den maximalen Wert des angegebenen Feldes der gefundenen Datensätze mit den angegebenen Kriterien bezogen auf die Gesamtmenge. Sie finden eine detaillierte Beschreibung im Beitrag Domänenfunktionen (www.access-im-unternehmen.de/317)

DSum

Diese Funktion ermittelt die Summe der Feldwerte des angegebenen Feldes der gefundenen Datensätze mit den angegebenen Kriterien. Sie finden eine detaillierte Beschreibung im Beitrag Domänenfunktionen (www.access-im-unternehmen.de/317)

DVar

Diese Funktion ermittelt die Varianz des angegebenen Feldes der gefundenen Datensätze mit den angegebenen Kriterien bezogen auf eine Stichprobe. Sie finden eine detaillierte Beschreibung im Beitrag Domänenfunktionen (www.access-im-unternehmen.de/317)

DVarP

Diese Funktion ermittelt die Varianz des angegebenen Feldes der gefundenen Datensätze mit den angegebenen Kriterien bezogen auf die Gesamtmenge. Sie finden eine detaillierte Beschreibung im Beitrag Domänenfunktionen (www.access-im-unternehmen.de/317)

Echo

Diese Methode gibt an, ob die Bildschirmanzeige aktualisiert werden soll. Der erste Parameter dieser Methode erwartet einen Integer-Wert, der angibt, ob die Aktualisierung der Bildschirmanzeige aktiviert (-1) oder deaktiviert werden soll (0). Der zweite Parameter verarbeitet eine Zeichenkette, die beim Aktivieren oder Deaktivieren in der Statusleiste ausgegeben wird.

Zum Deaktivieren verwenden Sie die folgende Anweisung:

Application.Echo False,  "Bildschirmaktualisierung deaktiviert."

Damit wird jegliche Aktivierung der Anzeige im Accessfenster deaktiviert. Zum Aktivieren verwenden Sie die folgende Anweisung:

Application.Echo True,  "Bildschirmaktualisierung aktiviert."

Sie können diese Methode nutzen, um bei Aktionen, die ein starkes Flackern verursachen, die Bildschirmaktualisierung bis zum Abschluss der auslösenden Aktion zu deaktivieren.

EuroConvert

Der Nutzen dieser Funktion, die Geldbeträge aus verschiedenen Währungen in Euro umrechnet, dürfte mittlerweile auch verschwindend gering sein. Falls Sie dennoch ein paar DM oder Gulden in der Schublade finden, können Sie mit EuroConvert herausfinden, wie viele Euro Sie dafür erhalten. Der Aufruf lautet beispielsweise:

Debug.Print Application.EuroConvert(100, "DEM", "EUR")

Sie können aber auch Umrechnungen der übrigen Währungen vornehmen – etwa von Gulden nach DM. Dabei wird der bei der Euro-Einführung gültige Umrechnungskurs zugrunde gelegt.

Ende des frei verfügbaren Teil. Wenn Du mehr lesen möchtest, hole Dir ...

den kompletten Artikel im PDF-Format mit Beispieldatenbank

diesen und alle anderen Artikel mit dem Jahresabo